/com	ANSYS 11.0
! Next100_pmt screen, photocathode at y=0 
v2=-.00550041 	! voltage @2cm
rw=.000015	!wire radius
xw=.00025	!wire location, x
yw=.01455	!wire location, y

ysa=.014
y2=.02
y0=0.000
dy=0.001
i=0
efy0=0
ymin=0

nx=20

nysa0=140
nya=50
nyw=nx
ny2=100

/PNUM,KP,1  
/PNUM,LINE,1
/PNUM,AREA,1
/PNUM,VOLU,0
/PNUM,NODE,0
/PNUM,TABN,0
/PNUM,SVAL,0
/NUMBER,0 
/psym,cs,1
/PSF,PRES,NORM,2,0,1
/SHRINK,0   
/ESHAPE,1   
/EFACET,1   
/RATIO,1,1,1

*do,i,0,13
y=y0+I*dy
nysa=nysa0-(i*10)

/prep7
et,1,121	!2d 8-node  estat solid
keyopt,1,3,0	!cartesian
mp,perx,1,1.
mp,perx,2,1.
mp,perx,3,1.

/com	 
k,1,,y
k,2,xw,y
k,4,xw,ysa
k,44,xw,yw-xw
k,5,xw,yw
k,51,xw,yw-rw
k,52,xw-rw,yw
k,53,xw,yw+rw
k,55,xw,yw+xw
k,6,xw,y2
k,7,,y2
k,8,,yw
k,9,,ysa

l,1,2,nx
l,2,4,nysa,-5
l,4,44,nya,-5
l,44,51,nyw

 
/com	LARC, P1, P2, PC, RAD

larc,52,51,5,rw,nyw
larc,53,52,5,rw,nyw
l,53,55,nx
l,55,6,ny2,-3
l,6,7,nx
l,7,8,ny2,-3
l,8,9,nya,-5
l,9,1,nysa,-5
l,4,9,nx
l,52,8,nx
l,8,44,nx
l,8,55,nx


al,1,2,13,12
al,3,15,11,13
al,4,5,14,15
al,6,7,16,14
al,8,9,10,16


mat,2
amesh,1
mat,3
amesh,2
mat,1
amesh,3,6

dl,1,1,volt,0
dl,9,5,volt,v2
dl,5,3,volt,0
dl,6,4,volt,0
save
fini

/solu
anty,stat
solve
fini

/post1
/gropts,view,1
set,last

/com	path,axx,2,6,200
/com	ppath,1,,0,0
/com	ppath,2,,0,.02
/com	pdef,efy,ef,y
/com	plpath,efy


*GET,ymin,NODE,1,loc,y
*GET,efy0,NODE,1,EF,y
*cfopen,efy0_cart,txt,,append
*vwrite,ymin,efy0
(f10.3,f10.7)
*CFCLOS
fini
parsav,all,pars,txt
/cle
parres,new,pars,txt
*enddo
/eof